Delphi Clinic

C++Builder Gate

Training & Consultancy

Delphi Notes Weblog

Dr.Bob's Webshop

Under The Hood #10 - How to Shoot the Screen See Also:  Delphi Papers and Dr.Bob's Examines Columns

The first solution (Delphi 1.x only) is to emulate a print screen keypress from within your 16-bits Windows program using the undocumented KeyboardEvent API:

  unit Shot;
  interface

    procedure ScreenShot;

  implementation
  uses
    WinTypes;

    procedure KeyboardEvent; far; external 'USER' index 289;

    procedure ScreenShot; assembler;
    asm
         mov   ax, VK_SNAPSHOT
         sub   bx, bx
         call  KeyboardEvent
    end {ScreenShot};
  end.

In fact, the Delphi-Way to do the same would be to get a handle to the entire DeskTopWindow using GetDeskTopWindow, and just BitBlt the contents of the corresponding DC to a TBitmap component. The result is copied to the Clipboard using Clipboard.Assign:

  unit Shot;
  interface

    procedure ScreenShot;

  implementation
  uses
  {$IFDEF WIN32}
    Windows,
  {$ELSE}
    WinTypes, WinProcs,
  {$ENDIF}
    Forms, Graphics, Clipbrd;

    procedure ScreenShot;
    var
      ScreenDC: HDC;
      ScreenHandle: HWnd;
      ScreenBitmap: TBitmap;
    begin
      ScreenHandle := GetDeskTopWindow;
      ScreenDC := GetDC(ScreenHandle);
      try
        ScreenBitmap := TBitMap.Create;
        try
          ScreenBitmap.Width := Screen.Width;
          ScreenBitmap.Height := Screen.Height;
          BitBlt(ScreenBitmap.Canvas.Handle, 0, 0,
              Screen.Width, Screen.Height, ScreenDC, 0, 0, SRCCOPY);
          Clipboard.Assign(ScreenBitmap)
        finally
          ScreenBitmap.Free
        end
      finally
        ReleaseDC(ScreenHandle, ScreenDC)
      end
    end {ScreenShot};
  end.

Of course, we can also use the bitmap image in the Clipboard to play a little further. For example by placing it inside a small image (102x77) that shows the entire screen in "stamp" format. All we need to do for this is to have a TImage on a Form, and execute Image1.Picture.Assign(Clipboard), as we can see in the following example program (a form with one button and one image only);

  unit Unit1;
  interface
  uses
    Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
    ExtCtrls, StdCtrls;

  type
    TForm1 = class(TForm)
      Button1: TButton;
      Image1: TImage;
      procedure Button1Click(Sender: TObject);
    private
      { Private declarations }
    public
      { Public declarations }
    end;

  var
    Form1: TForm1;

  implementation
  uses
    Shot, Clipbrd;
  {$R *.DFM}

  procedure TForm1.Button1Click(Sender: TObject);
  begin
    ScreenShot;
    Image1.Picture.Assign(Clipboard)
  end;

  end.

  program hood10;
  uses
    Forms,
    unit1 in 'unit1.pas' {Form1};

  begin
    Application.Initialize;
    Application.CreateForm(TForm1, Form1);
    Application.Run;
  end.